# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Dan McGee <dan@archlinux.org>
# Contributor: Jesús E. <heckyel@hyperbola.info>

pkgname=irssi
pkgver=1.0.5
_debver=1.0.5
_debrel=1
pkgrel=1.hyperbola1
pkgdesc='Modular text mode IRC client with Perl scripting'
url='https://irssi.org/'
arch=('i686' 'x86_64')
license=('GPL')
depends=('glib2' 'openssl')
makedepends=('quilt')
optdepends=('perl-libwww: for the scriptassist script')
backup=('etc/irssi.conf')
source=(https://debian.simnet.is/debian/pool/main/i/$pkgname/${pkgname}_$_debver-$_debrel.debian.tar.xz
        https://github.com/irssi/irssi/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz{,.asc})
sha512sums=('2a96ed4f25056576697ec3aa1b20003df435d9b88fee0dc5f7e30570647622579e560a19fddbac11db7d2da0d7de5ed1d33a70401ef8c173b1f95a2c5c9f47b8'
            'c3fa94b6ddfa30b18f5ae5de0e607a226eb6e2c20c03a712243b75e8b5896f353c1e7d096094f66e304b5b2691ad3479e26c024245b32b399f08e29815f02bfb'
            'SKIP')
validpgpkeys=('7EE65E3082A5FB06AC7C368D00CCB587DDBEF0E1') # The Irssi project <staff@irssi.org>

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av

  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --with-proxy \
    --with-perl-lib=vendor
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: